lib/App/LazyShoppingList/API/v1.pm

   1 use v5.26;
   2 use warnings;
   3 use utf8;
   4
   5 package App::LazyShoppingList::API::v1;
   6 use App::LazyShoppingList::API;
   7 use Dancer2;
   8
   9 our $VERSION = '0.1';
  10
  11 use JSON();
  12
  13 use experimental 'signatures';
  14
  15 set charset      => 'UTF-8';
  16 set serializer => 'JSON';
  17
  18 # get the URI for the list of shopping lists
  19 get '/' => sub {
  20     return { lists => uri_for('/list') };
  21 };
  22
  23 # get the list of shopping lists
  24 get '/list' => sub {
  25     my $dbh = get_database;
  26     $dbh->txn_begin;
  27
  28     my %r = ( lists_version => get_lists_version($dbh), lists => [] );
  29     for my $list (
  30         $dbh->resultset('ShoppingList')
  31         ->search( undef,
  32             { order_by => { -asc => 'name' } } )->all
  33         )
  34     {
  35         push @{ $r{lists} },
  36             { uri => uri_for( "/list/" . $list->id ), name => $list->name };
  37     }
  38
  39     $dbh->txn_commit;
  40     return \%r;
  41 };
  42
  43 # create shopping list
  44 post '/list' => sub {
  45     my $req = request_data;
  46
  47     my $name = $req->{name};
  48     unless ($name) {
  49         return exception 400, "Missing list name";
  50     }
  51
  52     my $dbh = get_database;
  53     $dbh->txn_begin;
  54     my $list = $dbh->resultset('ShoppingList')->create({
  55             name => $name});
  56     $list->discard_changes;
  57
  58     my  $lists_ver = increment_lists_version($dbh);
  59
  60     $dbh->txn_commit;
  61
  62     return {
  63         uri           => uri_for( '/list/' . $list->id ),
  64         version       => $list->version,
  65         lists_version => $lists_ver
  66     };
  67 };
  68
  69 # get shopping list items
  70 get '/list/:list_id' => sub {
  71     my $list_id = route_parameters->get('list_id');
  72     length($list_id) and $list_id =~ /^\d{1,18}$/ or return invalid_input;
  73
  74     my $dbh = get_database;
  75
  76     warn $dbh;
  77     my %r = ( items => [] );
  78     $dbh->txn_begin;
  79
  80     $r{lists_version} = get_lists_version($dbh);
  81
  82     my $list = $dbh->resultset('ShoppingList')->find($list_id);
  83
  84     unless ($list) {
  85         $dbh->txn_commit;
  86         return exception 404, "No list with that ID found";
  87     }
  88
  89     $r{version} = $list->version;
  90
  91     my @items = $dbh->resultset('ShoppingListItem')
  92         ->search( undef, { order_by => { -asc => 'id' } } )->all;
  93     for my $item (@items) {
  94         push @{ $r{items} },
  95             {   uri =>
  96                 uri_for( sprintf( "/list/%s/%s", $list->id, $item->id ) ),
  97                 description => $item->description,
  98                 done        => JSON->boolean( $item->done ),
  99                 version     => $item->version,
 100             };
 101     }
 102
 103     $dbh->txn_commit;
 104
 105     return \%r;
 106 };
 107
 108 # create shopping list item
 109 post '/list/:id' => sub {
 110     my $list_id = route_parameters->get('id');
 111     length($list_id) and $list_id =~ /^\d{1,18}$/
 112         or return invalid_input('bad list ID');
 113
 114     my $req = request_data;
 115
 116     my $descr = $req->{description};
 117     my $done  = JSON->boolean( $req->{done} // 0 );
 118
 119     my $dbh = get_database;
 120     $dbh->txn_begin;
 121
 122     my %r = (
 123         lists_version => get_lists_version($dbh),
 124     );
 125
 126     my $list = $dbh->resultset('ShoppingList')->find($list_id);
 127
 128     unless ($list) {
 129         $dbh->txn_commit;
 130         exception 404, "No such list";
 131     }
 132
 133     my $item = $dbh->resultset('ShoppingListItem')->create(
 134         {   shopping_list => $list->id,
 135             description   => $descr,
 136             done          => $done,
 137         }
 138     );
 139     $item->discard_changes;
 140
 141     $list->update( { version => $list->version + 1 } );
 142
 143     $r{uri} = uri_for( sprintf( "list/%s/%s", $list->id, $item->id ) );
 144     $r{version} = $item->version;
 145     $r{list_version} = $list->version;
 146
 147     $dbh->txn_commit;
 148
 149     return \%r;
 150 };
 151
 152 # modify shopping list item
 153 put '/list/:list_id/:item_id' => sub {
 154     my $list_id = route_parameters->get('list_id');
 155     length($list_id) and $list_id =~ /^\d{1,18}$/
 156         or return invalid_input('bad list ID');
 157
 158     my $item_id = route_parameters->get('item_id');
 159     length($item_id) and $item_id =~ /^\d{1,18}$/
 160         or return invalid_input('bad item ID');
 161
 162     my $req = request_data;
 163
 164     my $descr = $req->{description};
 165     my $done  = JSON->boolean( $req->{done} // 0 );
 166     my $version = $req->{version};
 167
 168     length($version) and $version =~ /^\d{1,18}$/
 169         or return invalid_input('bad version');
 170
 171     my $dbh = get_database;
 172     $dbh->txn_begin;
 173
 174     my %r = (
 175         lists_version => get_lists_version($dbh),
 176     );
 177
 178     my $list = $dbh->resultset('ShoppingList')->find($list_id);
 179     unless ($list) {
 180         $dbh->txn_commit;
 181         return exception 404, "No such list";
 182     }
 183
 184     my $item = $dbh->resultset('ShoppingListItem')->find({shopping_list => $list->id, id => $item_id});
 185     unless ($item) {
 186         $dbh->txn_commit;
 187         return exception 404, "No such item";
 188     }
 189
 190     # in case no real changes are needed will return the current state
 191     if (   defined($descr) and $descr ne ( $item->description // '' )
 192         or defined($done) and $done != $item->done )
 193     {
 194         unless ($version == $item->version) {
 195             $dbh->txn_commit;
 196             return exception 409, exception =>
 197                 sprintf( 'Outdated version (current is %d)', $item->version );
 198         }
 199
 200         $item->update({
 201             defined($descr) ? (description  => $descr) : (),
 202             defined($done) ? (done =>  $done) : (),
 203             version => $version + 1,
 204         });
 205
 206         $list->update( { version => $list->version + 1 } );
 207     }
 208
 209     $r{uri} = uri_for( sprintf( "list/%s/%s", $list->id, $item->id ) );
 210     $r{version} = $item->version;
 211     $r{list_version} = $list->version;
 212
 213     $dbh->txn_commit;
 214
 215     return \%r;
 216 };
 217
 218 true;