bin/mpd-feeder

   1 #!/usr/bin/perl
   2
   3 use v5.32;
   4
   5 use Getopt::Long ();
   6 use Log::Any qw($log);
   7 use Log::Any::Adapter Stderr => log_level => 'error';
   8 use Object::Pad;
   9 use Syntax::Keyword::Try;
  10
  11 class Options {
  12     use Log::Any qw($log);
  13     use Time::Duration qw(duration_exact);
  14     use Time::Duration::Parse qw(parse_duration);
  15     has $log_level           :reader = 'warn';
  16     has $target_queue_length :reader = 10;
  17     has $mpd_host            :reader = undef;
  18     has $mpd_port            :reader = undef;
  19     has $db_path             :reader = 'mpd-feeder';
  20     has $db_user             :reader = undef;
  21     has $db_password         :reader = undef;
  22     has $min_album_interval  :reader = parse_duration('5h');
  23     has $min_song_interval   :reader = parse_duration('13d');
  24     has $min_artist_interval :reader = parse_duration('1h 15m');
  25     has $skip_db_update      :reader = 0;
  26
  27     method parse_command_line {
  28         Getopt::Long::GetOptions(
  29             'log-level=s'               => \$log_level,
  30             'skip-db-update!'           => \$skip_db_update,
  31             'tql|target-queue-length=n' => sub {
  32                 $target_queue_length = parse_integer(pop);
  33             },
  34             'mpd-host=s'           => \$mpd_host,
  35             'mpd-port=s'           => \$mpd_port,
  36             'db-path=s'            => \$db_path,
  37             'db-user=s'            => \$db_user,
  38             'min-album-interval=s' => sub {
  39                 $min_album_interval = parse_duration(pop);
  40             },
  41             'min-sing-interval=s' => sub {
  42                 $min_song_interval = parse_duration(pop);
  43             },
  44             'min-artist-interval=s' => sub {
  45                 $min_artist_interval = parse_duration(pop);
  46             },
  47         ) or exit 1;
  48     }
  49
  50     sub handle_config_option( $ini, $section, $option, $target_ref,
  51         $converter = undef )
  52     {
  53         return undef unless exists $ini->{$section}{$option};
  54
  55         my $value = $ini->{$section}{$option};
  56
  57         $value = $converter->($value) if $converter;
  58
  59         $$target_ref = $value;
  60
  61         $log->trace("Option $section.$option = $value");
  62     }
  63
  64     method dump {
  65         say "[mpd-feeder]";
  66         say "log_level = $log_level";
  67         say "";
  68         say "[mpd]";
  69         say "host = " . ( $mpd_host // '' );
  70         say "port = " . ( $mpd_port // '' );
  71         say "";
  72         say "[queue]";
  73         say "target-length = $target_queue_length";
  74         say "min-song-interval = " . duration_exact($min_song_interval);
  75         say "min-album-interval = " . duration_exact($min_album_interval);
  76         say "min-artist-interval = " . duration_exact($min_artist_interval);
  77         say "";
  78         say "[db]";
  79         say "path = " .     ( $db_path     // '' );
  80         say "user = " .     ( $db_user     // '' );
  81         say "password = " . ( $db_password // '' );
  82     }
  83
  84     sub parse_integer($input) {
  85         die "Invalid integer value '$input'" unless $input =~ /^\+?\d{1,18}$/;
  86         return $input + 0;
  87     }
  88
  89     method parse_config_file($path) {
  90         $log->trace("Parsing configuration file $path");
  91
  92         use Config::INI::Reader;
  93         my $ini = Config::INI::Reader->read_file($path);
  94
  95         handle_config_option( $ini => mpd => host => \$mpd_host );
  96         handle_config_option( $ini => mpd => port => \$mpd_port );
  97
  98         handle_config_option( $ini => 'mpd-feeder' => log_level => \$log_level );
  99
 100         handle_config_option(
 101             $ini => queue => 'target-length' => \$target_queue_length,
 102             \&parse_integer
 103         );
 104         handle_config_option(
 105             $ini => queue => 'min-song-interval' => \$min_song_interval,
 106             \&parse_duration
 107         );
 108         handle_config_option(
 109             $ini => queue => 'min-album-interval' => \$min_album_interval,
 110             \&parse_duration
 111         );
 112         handle_config_option(
 113             $ini => queue => 'min-artist-interval' => \$min_artist_interval,
 114             \&parse_duration
 115         );
 116
 117         handle_config_option( $ini => db => path     => \$db_path );
 118         handle_config_option( $ini => db => user     => \$db_user );
 119         handle_config_option( $ini => db => password => \$db_password );
 120
 121         # FIXME: complain about unknown sections/parameters
 122     }
 123 }
 124
 125 class Feeder {
 126     has $cfg_file :reader;
 127     has $opt :reader;
 128     has $db;
 129     has $db_generation;
 130     has $db_needs_update :writer = 1;
 131     has $mpd :reader;
 132
 133 use constant DEFAULT_CONFIG_FILE => '/etc/mpd-feeder/mpd-feeder.conf';
 134
 135 use DBD::Pg;
 136 use DBI;
 137 use Log::Any qw($log);
 138 use IO::Async::Signal;
 139 use Net::Async::MPD;
 140
 141     ADJUST {
 142         Getopt::Long::Configure('pass_through');
 143         Getopt::Long::GetOptions('cfg|config=s' => \$cfg_file);
 144         Getopt::Long::Configure('no_pass_through');
 145
 146         $cfg_file //= DEFAULT_CONFIG_FILE if -e DEFAULT_CONFIG_FILE;
 147
 148         $self->configure;
 149
 150         $db_needs_update = 0 if $opt->skip_db_update;
 151     }
 152
 153     method configure {
 154         my $new_opt = Options->new;
 155
 156         $new_opt->parse_config_file($cfg_file) if $cfg_file;
 157
 158         $new_opt->parse_command_line;
 159
 160         Log::Any::Adapter->set( Stderr => log_level => $new_opt->log_level );
 161
 162         $opt = $new_opt;
 163     }
 164
 165     method connect_mpd {
 166         return if $mpd;
 167
 168         my %conn = ( auto_connect => 1 );
 169         $conn{host} = $opt->mpd_host if $opt->mpd_host;
 170         $conn{port} = $opt->mpd_port if $opt->mpd_port;
 171
 172         $mpd = Net::Async::MPD->new(%conn);
 173
 174         $mpd->loop->add(
 175             IO::Async::Signal->new(
 176                 name       => 'HUP',
 177                 on_receipt => sub {
 178                     $log->debug("SIGHUP received. Stopping loop");
 179                     $mpd->loop->stop('reload');
 180                 },
 181             )
 182         );
 183
 184         $mpd->loop->add(
 185             IO::Async::Signal->new(
 186                 name       => 'USR1',
 187                 on_receipt => sub {
 188                     $log->debug("SIGUSR1 received. Dumping configuration to STDERR");
 189                     my $old = select \*STDERR;
 190                     try {
 191                         $opt->dump;
 192                     }
 193                     finally {
 194                         select $old;
 195                     }
 196                 },
 197             )
 198         );
 199     }
 200
 201     method connect_db {
 202         return if $db;
 203
 204         $db = DBI->connect( "dbi:Pg:dbname=" . $opt->db_path,
 205             $opt->db_user, $opt->db_password,
 206             { RaiseError => 1, PrintError => 0, AutoCommit => 1 } );
 207
 208         $log->info( "Connected to database " . $opt->db_path );
 209         $db_generation = $self->db_get_option('generation');
 210         $log->debug("DB generation is $db_generation");
 211         $self->update_db;
 212     }
 213
 214     method db_get_option($name) {
 215         my $sth = $db->prepare_cached("select $name from options");
 216         $sth->execute;
 217         my @result = $sth->fetchrow_array;
 218         $sth->finish;
 219         undef $sth;
 220
 221         return $result[0];
 222     }
 223
 224     method db_set_option( $name, $value ) {
 225         my $sth = $db->prepare_cached("update options set $name = ?");
 226         $sth->execute($value);
 227     }
 228
 229     method db_store_song($song, $artist, $album) {
 230         return unless length($song) and length($artist) and length($album);
 231
 232         $db->prepare_cached(
 233             <<'SQL')->execute( $song, $artist, $album, $db_generation );
 234 INSERT INTO songs(path, artist, album, generation)
 235 VALUES($1, $2, $3, $4)
 236 ON CONFLICT ON CONSTRAINT songs_pkey DO
 237 UPDATE SET artist = $2
 238          , album = $3
 239          , generation = $4
 240 SQL
 241         $db->prepare_cached(<<'SQL')->execute( $artist, $album, $db_generation );
 242 INSERT INTO albums(artist, album, generation)
 243 VALUES($1, $2, $3)
 244 ON CONFLICT ON CONSTRAINT albums_pkey DO
 245 UPDATE SET generation = $3
 246 SQL
 247         $db->prepare_cached(<<'SQL')->execute( $artist, $db_generation );
 248 INSERT INTO artists(artist, generation)
 249 VALUES($1, $2)
 250 ON CONFLICT ON CONSTRAINT artists_pkey DO
 251 UPDATE SET generation = $2
 252 SQL
 253     }
 254
 255     method db_remove_stale_entries {
 256         my $sth =
 257             $db->prepare_cached('DELETE FROM songs WHERE generation <> ?');
 258         $sth->execute($db_generation);
 259         $log->debug( sprintf( "Deleted %d stale songs", $sth->rows ) );
 260
 261         $sth = $db->prepare_cached('DELETE FROM albums WHERE generation <> ?');
 262         $sth->execute($db_generation);
 263         $log->debug( sprintf( "Deleted %d stale albums", $sth->rows ) );
 264
 265         $sth =
 266             $db->prepare_cached('DELETE FROM artists WHERE generation <> ?');
 267         $sth->execute($db_generation);
 268         $log->debug( sprintf( "Deleted %d stale artists", $sth->rows ) );
 269     }
 270
 271     method db_note_song_qeued($item) {
 272         $db->prepare_cached(
 273             'UPDATE songs SET last_queued=current_timestamp WHERE path=?')
 274             ->execute( $item->{song} );
 275         $db->prepare_cached(
 276             'UPDATE artists SET last_queued=CURRENT_TIMESTAMP WHERE artist=?')
 277             ->execute( $item->{artist} );
 278         $db->prepare_cached(
 279             'UPDATE albums SET last_queued=CURRENT_TIMESTAMP WHERE artist=? AND album=?'
 280         )->execute( $item->{artist}, $item->{album} );
 281     }
 282
 283     method update_db($force = undef) {
 284         if (!$db_needs_update and !$force) {
 285             $log->debug("Skipping DB update");
 286             return;
 287         }
 288
 289         $log->info('Updating song database');
 290         $self->connect_mpd;
 291         $self->connect_db;
 292
 293         my $rows = $mpd->send('listallinfo')->get;
 294         try {
 295             $db->begin_work;
 296
 297             $db_generation++;
 298
 299             my $song_count;
 300
 301             foreach my $entry (@$rows) {
 302                 next unless exists $entry->{file};
 303                 $self->db_store_song( $entry->{file},
 304                     $entry->{AlbumArtist} // $entry->{Artist},
 305                     $entry->{Album} );
 306                 $song_count++;
 307             }
 308
 309             $log->info("Updated data about $song_count songs");
 310
 311             $self->db_remove_stale_entries;
 312
 313             $self->db_set_option( generation => $db_generation );
 314
 315             $db->commit;
 316
 317             $db_needs_update = 0;
 318         }
 319         catch {
 320             my $err = $@;
 321
 322             $db_generation--;
 323
 324             $db->rollback;
 325
 326             die $err;
 327         }
 328     }
 329
 330     method db_find_suitable_songs($num) {
 331         $self->connect_db;
 332         $self->update_db;
 333
 334         my @result;
 335         my $sql = <<SQL;
 336 SELECT s.path, s.artist, s.album
 337 FROM songs s
 338 JOIN artists ar ON ar.artist=s.artist
 339 JOIN albums al ON al.album=s.album AND al.artist=s.artist
 340 WHERE (s.last_queued IS NULL OR s.last_queued < CURRENT_TIMESTAMP - (? || ' seconds')::interval)
 341   AND (ar.last_queued IS NULL OR ar.last_queued < CURRENT_TIMESTAMP - (? || ' seconds')::interval)
 342   AND (al.last_queued IS NULL OR al.last_queued < CURRENT_TIMESTAMP - (? || ' seconds')::interval)
 343   AND NOT EXISTS (SELECT 1 FROM unwanted_artists uar WHERE uar.artist = s.artist)
 344   AND NOT EXISTS (SELECT 1 FROM unwanted_albums  ual WHERE ual.album  = s.album)
 345 ORDER BY random()
 346 LIMIT ?
 347 SQL
 348         my @params = (
 349             $opt->min_song_interval,  $opt->min_artist_interval,
 350             $opt->min_album_interval, $num,
 351         );
 352         my $sth = $db->prepare_cached($sql);
 353         $sth->execute(@params);
 354         while ( my @row = $sth->fetchrow_array ) {
 355             push @result,
 356                 { song => $row[0], artist => $row[1], album => $row[2] };
 357         }
 358         undef $sth;
 359
 360         return @result;
 361     }
 362
 363     method db_add_unwanted_artist($artist) {
 364         $self->connect_db;
 365
 366         try {
 367             $db->do(
 368                 <<'SQL',
 369 INSERT INTO unwanted_artists(artist, generation)
 370 VALUES($1, $2)
 371 SQL
 372                 undef, $artist, $db_generation
 373             );
 374             return 1;
 375         }
 376         catch {
 377             my $err = $@;
 378
 379             $log->debug("PostgreSQL error: $err");
 380             $log->debug( "SQLSTATE = " . $db->state );
 381             return 0 if $db->state eq '23505';
 382
 383             die $err;
 384         }
 385     }
 386
 387     method db_del_unwanted_artist($artist) {
 388         $self->connect_db;
 389
 390         return 1 == $db->do(
 391             <<'SQL',
 392 DELETE FROM unwanted_artists
 393 WHERE artist = $1
 394 SQL
 395             undef, $artist
 396         );
 397     }
 398
 399     method queue_songs($num = undef, $callback = undef) {
 400         if (!defined $num) {
 401             $self->connect_mpd;
 402             $mpd->send('playlist')->on_done(
 403                 sub {
 404                     my $present = scalar @{ $_[0] };
 405
 406                     $log->notice( "Playlist contains $present songs. Wanted: "
 407                             . $opt->target_queue_length );
 408                     if ( $present < $opt->target_queue_length ) {
 409                         $self->queue_songs(
 410                             $opt->target_queue_length - $present, $callback );
 411                     }
 412                     else {
 413                         $callback->() if $callback;
 414                     }
 415                 }
 416             );
 417
 418             return;
 419         }
 420
 421         my @list = $self->db_find_suitable_songs($num);
 422
 423         die "Found no suitable songs" unless @list;
 424
 425         if ( @list < $num ) {
 426             $log->warn(
 427                 sprintf(
 428                     'Found only %d suitable songs instead of %d',
 429                     scalar(@list), $num
 430                 )
 431             );
 432         }
 433
 434         $log->info("About to add $num songs to the playlist");
 435
 436         my @paths;
 437         for my $song (@list) {
 438             my $path = $song->{song};
 439             $path =~ s/"/\\"/g;
 440             push @paths, $path;
 441         }
 442
 443         $log->debug( "Adding " . join( ', ', map {"«$_»"} @paths ) );
 444         my @commands;
 445         for (@paths) {
 446             push @commands, [ add => "\"$_\"" ];
 447         }
 448         $self->connect_mpd;
 449         my $f = $mpd->send( \@commands );
 450         $f->on_fail( sub { die @_ } );
 451         $f->on_done(
 452             sub {
 453                 $self->db_note_song_qeued($_) for @list;
 454                 $callback->(@_) if $callback;
 455             }
 456         );
 457     }
 458
 459     method prepare_to_wait_idle {
 460         $log->trace('declaring idle mode');
 461         $mpd->send('idle database playlist')->on_done(
 462             sub {
 463                 my $result = shift;
 464
 465                 if ( $result->{changed} eq 'database' ) {
 466                     $db_needs_update = 1;
 467                     $self->prepare_to_wait_idle;
 468                 }
 469                 elsif ( $result->{changed} eq 'playlist' ) {
 470                     $self->queue_songs( undef,
 471                         sub { $self->prepare_to_wait_idle } );
 472                 }
 473                 else {
 474                     use JSON;
 475                     $log->warn(
 476                         "Unknown result from idle: " . to_json($result) );
 477                     $self->prepare_to_wait_idle;
 478                 }
 479             }
 480         );
 481     }
 482
 483     method run {
 484         $mpd->on(
 485             close => sub {
 486                 die "Connection to MPD lost";
 487             }
 488         );
 489
 490         $self->prepare_to_wait_idle;
 491     }
 492
 493     method stop {
 494         undef $mpd;
 495
 496         if ($db) {
 497             if ($db->{ActiveKids}) {
 498                 $log->warn("$db->{ActiveKids} active DB statements");
 499                 for my $st ( @{ $db->{ChildHandles} } ) {
 500                     next unless $st->{Active};
 501                     while(my($k,$v) = each %$st) {
 502                         $log->debug("$k = ".($v//'<NULL>'));
 503                     }
 504                 }
 505             }
 506
 507             $db->disconnect;
 508             undef $db;
 509         }
 510     }
 511 }
 512
 513 my $feeder = Feeder->new();
 514
 515 if (@ARGV) {
 516     my $cmd = shift @ARGV;
 517
 518     if ($cmd eq 'dump-config') {
 519         die "dump-config command accepts no arguments\n" if @ARGV;
 520
 521         $feeder->opt->dump;
 522         exit;
 523     }
 524
 525     if ( $cmd eq 'add-unwanted-artist' ) {
 526         die "Missing command arguments\n" unless @ARGV;
 527         $feeder->set_db_needs_update(0);
 528         for my $artist (@ARGV) {
 529             if ( $feeder->db_add_unwanted_artist($artist) ) {
 530                 $log->info("Artist '$artist' added to the unwanted list\n");
 531             }
 532             else {
 533                 $log->warn("Artist '$artist' already in the unwanted list\n");
 534             }
 535         }
 536         exit;
 537     }
 538
 539     if ( $cmd eq 'del-unwanted-artist' ) {
 540         die "Missing command arguments\n" unless @ARGV;
 541         $feeder->set_db_needs_update(0);
 542         for my $artist (@ARGV) {
 543             if ( $feeder->db_del_unwanted_artist($artist) ) {
 544                 $log->info("Artist '$artist' deleted from the unwanted list\n");
 545             }
 546             else {
 547                 $log->warn("Artist '$artist' is not in the unwanted list\n");
 548             }
 549         }
 550         exit;
 551     }
 552
 553     if ( $cmd eq 'add-unwanted-album' ) {
 554         die "NOT IMPLEMENTED\n";
 555     }
 556
 557     if ( $cmd eq 'one-shot' ) {
 558         die "one-shot command accepts no arguments\n" if @ARGV;
 559
 560         $feeder->queue_songs(undef, sub { exit });
 561         $feeder->mpd->loop->run;
 562     }
 563     elsif ( $cmd eq 'single' ) {
 564         die "single command accepts no arguments\n" if @ARGV;
 565
 566         $feeder->queue_songs(1, sub { exit });
 567         $feeder->mpd->loop->run;
 568     }
 569     else {
 570         die "Unknown command '$cmd'";
 571     }
 572 }
 573
 574 $feeder->connect_db;
 575
 576 for ( ;; ) {
 577     $feeder->queue_songs( undef, sub { $feeder->run } );
 578
 579     $log->debug("Entering event loop. PID=$$");
 580
 581     my $result = $feeder->mpd->loop->run;
 582     $log->trace( "Got loop result of " . ( $result // 'undef' ) );
 583
 584     if ('reload' eq $result) {
 585         $log->notice("disconnecting");
 586         $feeder->stop;
 587
 588         exec( "$0", '--config', $feeder->cfg_file, '--skip-db-update' );
 589     }
 590 }