bin/mpd-feeder

   1 #!/usr/bin/perl
   2
   3 use v5.32;
   4
   5 use Getopt::Long ();
   6 use Log::Any qw($log);
   7 use Log::Any::Adapter Stderr => log_level => 'error';
   8 use Object::Pad;
   9 use Syntax::Keyword::Try;
  10
  11 class Options {
  12     use Log::Any qw($log);
  13     use Time::Duration qw(duration_exact);
  14     use Time::Duration::Parse qw(parse_duration);
  15     has $log_level           :reader = 'warn';
  16     has $target_queue_length :reader = 10;
  17     has $mpd_host            :reader = undef;
  18     has $mpd_port            :reader = undef;
  19     has $db_path             :reader = 'mpd-feeder';
  20     has $db_user             :reader = undef;
  21     has $db_password         :reader = undef;
  22     has $min_album_interval  :reader = parse_duration('5h');
  23     has $min_song_interval   :reader = parse_duration('13d');
  24     has $min_artist_interval :reader = parse_duration('1h 15m');
  25     has $skip_db_update      :reader = 0;
  26
  27     method parse_command_line {
  28         Getopt::Long::GetOptions(
  29             'log-level=s'               => \$log_level,
  30             'skip-db-update!'           => \$skip_db_update,
  31             'tql|target-queue-length=n' => sub {
  32                 $target_queue_length = parse_integer(pop);
  33             },
  34             'mpd-host=s'           => \$mpd_host,
  35             'mpd-port=s'           => \$mpd_port,
  36             'db-path=s'            => \$db_path,
  37             'db-user=s'            => \$db_user,
  38             'min-album-interval=s' => sub {
  39                 $min_album_interval = parse_duration(pop);
  40             },
  41             'min-sing-interval=s' => sub {
  42                 $min_song_interval = parse_duration(pop);
  43             },
  44             'min-artist-interval=s' => sub {
  45                 $min_artist_interval = parse_duration(pop);
  46             },
  47         ) or exit 1;
  48     }
  49
  50     sub handle_config_option( $ini, $section, $option, $target_ref,
  51         $converter = undef )
  52     {
  53         return undef unless exists $ini->{$section}{$option};
  54
  55         my $value = $ini->{$section}{$option};
  56
  57         $value = $converter->($value) if $converter;
  58
  59         $$target_ref = $value;
  60
  61         $log->trace("Option $section.$option = $value");
  62     }
  63
  64     method dump {
  65         say "[mpd-feeder]";
  66         say "log_level = $log_level";
  67         say "";
  68         say "[mpd]";
  69         say "host = " . ( $mpd_host // '' );
  70         say "port = " . ( $mpd_port // '' );
  71         say "";
  72         say "[queue]";
  73         say "target-length = $target_queue_length";
  74         say "min-song-interval = " . duration_exact($min_song_interval);
  75         say "min-album-interval = " . duration_exact($min_album_interval);
  76         say "min-artist-interval = " . duration_exact($min_artist_interval);
  77         say "";
  78         say "[db]";
  79         say "path = " .     ( $db_path     // '' );
  80         say "user = " .     ( $db_user     // '' );
  81         say "password = " . ( $db_password // '' );
  82     }
  83
  84     sub parse_integer($input) {
  85         die "Invalid integer value '$input'" unless $input =~ /^\+?\d{1,18}$/;
  86         return $input + 0;
  87     }
  88
  89     method parse_config_file($path) {
  90         $log->trace("Parsing configuration file $path");
  91
  92         use Config::INI::Reader;
  93         my $ini = Config::INI::Reader->read_file($path);
  94
  95         handle_config_option( $ini => mpd => host => \$mpd_host );
  96         handle_config_option( $ini => mpd => port => \$mpd_port );
  97
  98         handle_config_option( $ini => 'mpd-feeder' => log_level => \$log_level );
  99
 100         handle_config_option(
 101             $ini => queue => 'target-length' => \$target_queue_length,
 102             \&parse_integer
 103         );
 104         handle_config_option(
 105             $ini => queue => 'min-song-interval' => \$min_song_interval,
 106             \&parse_duration
 107         );
 108         handle_config_option(
 109             $ini => queue => 'min-album-interval' => \$min_album_interval,
 110             \&parse_duration
 111         );
 112         handle_config_option(
 113             $ini => queue => 'min-artist-interval' => \$min_artist_interval,
 114             \&parse_duration
 115         );
 116
 117         handle_config_option( $ini => db => path     => \$db_path );
 118         handle_config_option( $ini => db => user     => \$db_user );
 119         handle_config_option( $ini => db => password => \$db_password );
 120
 121         # FIXME: complain about unknown sections/parameters
 122     }
 123 }
 124
 125 class Feeder {
 126     has $cfg_file :reader;
 127     has $opt :reader;
 128     has $db;
 129     has $db_generation;
 130     has $db_needs_update :writer = 1;
 131     has $mpd :reader;
 132
 133 use constant DEFAULT_CONFIG_FILE => '/etc/mpd-feeder/mpd-feeder.conf';
 134
 135 use DBD::Pg;
 136 use DBI;
 137 use Log::Any qw($log);
 138 use IO::Async::Signal;
 139 use Net::Async::MPD;
 140
 141     ADJUST {
 142         Getopt::Long::Configure('pass_through');
 143         Getopt::Long::GetOptions('cfg|config=s' => \$cfg_file);
 144         Getopt::Long::Configure('no_pass_through');
 145
 146         $cfg_file //= DEFAULT_CONFIG_FILE if -e DEFAULT_CONFIG_FILE;
 147
 148         $self->configure;
 149
 150         $db_needs_update = 0 if $opt->skip_db_update;
 151     }
 152
 153     method configure {
 154         my $new_opt = Options->new;
 155
 156         $new_opt->parse_config_file($cfg_file) if $cfg_file;
 157
 158         $new_opt->parse_command_line;
 159
 160         Log::Any::Adapter->set( Stderr => log_level => $new_opt->log_level );
 161
 162         $opt = $new_opt;
 163     }
 164
 165     method connect_mpd {
 166         return if $mpd;
 167
 168         my %conn = ( auto_connect => 1 );
 169         $conn{host} = $opt->mpd_host if $opt->mpd_host;
 170         $conn{port} = $opt->mpd_port if $opt->mpd_port;
 171
 172         $mpd = Net::Async::MPD->new(%conn);
 173
 174         $mpd->loop->add(
 175             IO::Async::Signal->new(
 176                 name       => 'HUP',
 177                 on_receipt => sub {
 178                     $log->debug("SIGHUP received. Stopping loop");
 179                     $mpd->loop->stop('reload');
 180                 },
 181             )
 182         );
 183
 184         $mpd->loop->add(
 185             IO::Async::Signal->new(
 186                 name       => 'USR1',
 187                 on_receipt => sub {
 188                     $log->debug("SIGUSR1 received. Dumping configuration to STDERR");
 189                     my $old = select \*STDERR;
 190                     try {
 191                         $opt->dump;
 192                     }
 193                     finally {
 194                         select $old;
 195                     }
 196                 },
 197             )
 198         );
 199     }
 200
 201     method connect_db {
 202         return if $db;
 203
 204         $db = DBI->connect( "dbi:Pg:dbname=" . $opt->db_path,
 205             $opt->db_user, $opt->db_password,
 206             { RaiseError => 1, PrintError => 0, AutoCommit => 1 } );
 207
 208         $log->info( "Connected to database " . $opt->db_path );
 209         $db_generation = $self->db_get_option('generation');
 210         $log->debug("DB generation is $db_generation");
 211         $self->update_db;
 212     }
 213
 214     method db_get_option($name) {
 215         my $sth = $db->prepare_cached("select $name from options");
 216         $sth->execute;
 217         my @result = $sth->fetchrow_array;
 218
 219         return $result[0];
 220     }
 221
 222     method db_set_option( $name, $value ) {
 223         my $sth = $db->prepare_cached("update options set $name = ?");
 224         $sth->execute($value);
 225     }
 226
 227     method db_store_song($song, $artist, $album) {
 228         return unless length($song) and length($artist) and length($album);
 229
 230         $db->prepare_cached(
 231             <<'SQL')->execute( $song, $artist, $album, $db_generation );
 232 INSERT INTO songs(path, artist, album, generation)
 233 VALUES($1, $2, $3, $4)
 234 ON CONFLICT ON CONSTRAINT songs_pkey DO
 235 UPDATE SET artist = $2
 236          , album = $3
 237          , generation = $4
 238 SQL
 239         $db->prepare_cached(<<'SQL')->execute( $artist, $album, $db_generation );
 240 INSERT INTO albums(artist, album, generation)
 241 VALUES($1, $2, $3)
 242 ON CONFLICT ON CONSTRAINT albums_pkey DO
 243 UPDATE SET generation = $3
 244 SQL
 245         $db->prepare_cached(<<'SQL')->execute( $artist, $db_generation );
 246 INSERT INTO artists(artist, generation)
 247 VALUES($1, $2)
 248 ON CONFLICT ON CONSTRAINT artists_pkey DO
 249 UPDATE SET generation = $2
 250 SQL
 251     }
 252
 253     method db_remove_stale_entries {
 254         my $sth =
 255             $db->prepare_cached('DELETE FROM songs WHERE generation <> ?');
 256         $sth->execute($db_generation);
 257         $log->debug( sprintf( "Deleted %d stale songs", $sth->rows ) );
 258
 259         $sth = $db->prepare_cached('DELETE FROM albums WHERE generation <> ?');
 260         $sth->execute($db_generation);
 261         $log->debug( sprintf( "Deleted %d stale albums", $sth->rows ) );
 262
 263         $sth =
 264             $db->prepare_cached('DELETE FROM artists WHERE generation <> ?');
 265         $sth->execute($db_generation);
 266         $log->debug( sprintf( "Deleted %d stale artists", $sth->rows ) );
 267     }
 268
 269     method db_note_song_qeued($item) {
 270         $db->prepare_cached(
 271             'UPDATE songs SET last_queued=current_timestamp WHERE path=?')
 272             ->execute( $item->{song} );
 273         $db->prepare_cached(
 274             'UPDATE artists SET last_queued=CURRENT_TIMESTAMP WHERE artist=?')
 275             ->execute( $item->{artist} );
 276         $db->prepare_cached(
 277             'UPDATE albums SET last_queued=CURRENT_TIMESTAMP WHERE artist=? AND album=?'
 278         )->execute( $item->{artist}, $item->{album} );
 279     }
 280
 281     method update_db($force = undef) {
 282         if (!$db_needs_update and !$force) {
 283             $log->debug("Skipping DB update");
 284             return;
 285         }
 286
 287         $log->info('Updating song database');
 288         $self->connect_mpd;
 289         $self->connect_db;
 290
 291         my $rows = $mpd->send('listallinfo')->get;
 292         try {
 293             $db->begin_work;
 294
 295             $db_generation++;
 296
 297             my $song_count;
 298
 299             foreach my $entry (@$rows) {
 300                 next unless exists $entry->{file};
 301                 $self->db_store_song( $entry->{file},
 302                     $entry->{Artist}, $entry->{Album} );
 303                 $song_count++;
 304             }
 305
 306             $log->info("Updated data about $song_count songs");
 307
 308             $self->db_remove_stale_entries;
 309
 310             $self->db_set_option( generation => $db_generation );
 311
 312             $db->commit;
 313
 314             $db_needs_update = 0;
 315         }
 316         catch {
 317             my $err = $@;
 318
 319             $db_generation--;
 320
 321             $db->rollback;
 322
 323             die $err;
 324         }
 325     }
 326
 327     method db_find_suitable_songs($num) {
 328         $self->connect_db;
 329         $self->update_db;
 330
 331         my @result;
 332         my $sth = $db->prepare_cached(<<SQL);
 333 SELECT s.path, s.artist, s.album
 334 FROM songs s
 335 JOIN artists ar ON ar.artist=s.artist
 336 JOIN albums al ON al.album=s.album
 337 WHERE (s.last_queued IS NULL OR s.last_queued < CURRENT_TIMESTAMP - (? || ' seconds')::interval)
 338   AND (ar.last_queued IS NULL OR ar.last_queued < CURRENT_TIMESTAMP - (? || ' seconds')::interval)
 339   AND (al.last_queued IS NULL OR al.last_queued < CURRENT_TIMESTAMP - (? || ' seconds')::interval)
 340   AND NOT EXISTS (SELECT 1 FROM unwanted_artists uar WHERE uar.artist = s.artist)
 341   AND NOT EXISTS (SELECT 1 FROM unwanted_albums  ual WHERE ual.album  = s.album)
 342 ORDER BY random()
 343 LIMIT ?
 344 SQL
 345         $sth->execute(
 346             $opt->min_song_interval,
 347             $opt->min_artist_interval,
 348             $opt->min_album_interval,
 349             $num,
 350         );
 351         while ( my @row = $sth->fetchrow_array ) {
 352             push @result,
 353                 { song => $row[0], artist => $row[1], album => $row[2] };
 354         }
 355
 356         return @result;
 357     }
 358
 359     method db_add_unwanted_artist($artist) {
 360         $self->connect_db;
 361
 362         try {
 363             $db->do(
 364                 <<'SQL',
 365 INSERT INTO unwanted_artists(artist, generation)
 366 VALUES($1, $2)
 367 SQL
 368                 undef, $artist, $db_generation
 369             );
 370             return 1;
 371         }
 372         catch {
 373             my $err = $@;
 374
 375             $log->debug("PostgreSQL error: $err");
 376             $log->debug( "SQLSTATE = " . $db->state );
 377             return 0 if $db->state eq '23505';
 378
 379             die $err;
 380         }
 381     }
 382
 383     method db_del_unwanted_artist($artist) {
 384         $self->connect_db;
 385
 386         return 1 == $db->do(
 387             <<'SQL',
 388 DELETE FROM unwanted_artists
 389 WHERE artist = $1
 390 SQL
 391             undef, $artist
 392         );
 393     }
 394
 395     method queue_songs($num = undef, $callback = undef) {
 396         if (!defined $num) {
 397             $self->connect_mpd;
 398             $mpd->send('playlist')->on_done(
 399                 sub {
 400                     my $present = scalar @{ $_[0] };
 401
 402                     $log->notice("Playlist contains $present songs");
 403                     if ( $present < $opt->target_queue_length ) {
 404                         $self->queue_songs(
 405                             $opt->target_queue_length - $present, $callback );
 406                     }
 407                     else {
 408                         $callback->() if $callback;
 409                     }
 410                 }
 411             );
 412
 413             return;
 414         }
 415
 416         my @list = $self->db_find_suitable_songs($num);
 417
 418         die "Found no suitable songs" unless @list;
 419
 420         if ( @list < $num ) {
 421             $log->warn(
 422                 sprintf(
 423                     'Found only %d suitable songs instead of %d',
 424                     scalar(@list), $num
 425                 )
 426             );
 427         }
 428
 429         $log->info("About to add $num songs to the playlist");
 430
 431         my @paths;
 432         for my $song (@list) {
 433             my $path = $song->{song};
 434             $path =~ s/"/\\"/g;
 435             push @paths, $path;
 436         }
 437
 438         $log->debug( "Adding " . join( ', ', map {"«$_»"} @paths ) );
 439         my @commands;
 440         for (@paths) {
 441             push @commands, [ add => "\"$_\"" ];
 442         }
 443         $self->connect_mpd;
 444         my $f = $mpd->send( \@commands );
 445         $f->on_fail( sub { die @_ } );
 446         $f->on_done(
 447             sub {
 448                 $self->db_note_song_qeued($_) for @list;
 449                 $callback->(@_) if $callback;
 450             }
 451         );
 452     }
 453
 454     method prepare_to_wait_idle {
 455         $log->trace('declaring idle mode');
 456         $mpd->send('idle database playlist')->on_done(
 457             sub {
 458                 my $result = shift;
 459
 460                 if ( $result->{changed} eq 'database' ) {
 461                     $db_needs_update = 1;
 462                     $self->prepare_to_wait_idle;
 463                 }
 464                 elsif ( $result->{changed} eq 'playlist' ) {
 465                     $self->queue_songs( undef,
 466                         sub { $self->prepare_to_wait_idle } );
 467                 }
 468                 else {
 469                     use JSON;
 470                     $log->warn(
 471                         "Unknown result from idle: " . to_json($result) );
 472                     $self->prepare_to_wait_idle;
 473                 }
 474             }
 475         );
 476     }
 477
 478     method run {
 479         $mpd->on(
 480             close => sub {
 481                 die "Connection to MPD lost";
 482             }
 483         );
 484
 485         $self->prepare_to_wait_idle;
 486     }
 487
 488     method stop {
 489         undef $mpd;
 490
 491         if ($db) {
 492             if ($db->{ActiveKids}) {
 493                 $log->warn("$db->{ActiveKids} active DB statements");
 494                 for my $st ( @{ $db->{ChildHandles} } ) {
 495                     next unless $st->{Active};
 496                     while(my($k,$v) = each %$st) {
 497                         $log->debug("$k = ".($v//'<NULL>'));
 498                     }
 499                 }
 500             }
 501
 502             $db->disconnect;
 503             undef $db;
 504         }
 505     }
 506 }
 507
 508 my $feeder = Feeder->new();
 509
 510 if (@ARGV) {
 511     my $cmd = shift @ARGV;
 512
 513     if ($cmd eq 'dump-config') {
 514         die "dump-config command accepts no arguments\n" if @ARGV;
 515
 516         $feeder->opt->dump;
 517         exit;
 518     }
 519
 520     if ( $cmd eq 'add-unwanted-artist' ) {
 521         die "Missing command arguments\n" unless @ARGV;
 522         $feeder->set_db_needs_update(0);
 523         for my $artist (@ARGV) {
 524             if ( $feeder->db_add_unwanted_artist($artist) ) {
 525                 $log->info("Artist '$artist' added to the unwanted list\n");
 526             }
 527             else {
 528                 $log->warn("Artist '$artist' already in the unwanted list\n");
 529             }
 530         }
 531         exit;
 532     }
 533
 534     if ( $cmd eq 'del-unwanted-artist' ) {
 535         die "Missing command arguments\n" unless @ARGV;
 536         $feeder->set_db_needs_update(0);
 537         for my $artist (@ARGV) {
 538             if ( $feeder->db_del_unwanted_artist($artist) ) {
 539                 $log->info("Artist '$artist' deleted from the unwanted list\n");
 540             }
 541             else {
 542                 $log->warn("Artist '$artist' is not in the unwanted list\n");
 543             }
 544         }
 545         exit;
 546     }
 547
 548     if ( $cmd eq 'add-unwanted-album' ) {
 549         die "NOT IMPLEMENTED\n";
 550     }
 551
 552     if ( $cmd eq 'one-shot' ) {
 553         die "one-shot command accepts no arguments\n" if @ARGV;
 554
 555         $feeder->queue_songs(undef, sub { exit });
 556         $feeder->mpd->loop->run;
 557     }
 558     elsif ( $cmd eq 'single' ) {
 559         die "single command accepts no arguments\n" if @ARGV;
 560
 561         $feeder->queue_songs(1, sub { exit });
 562         $feeder->mpd->loop->run;
 563     }
 564     else {
 565         die "Unknown command '$cmd'";
 566     }
 567 }
 568
 569 for ( ;; ) {
 570     $feeder->queue_songs( undef, sub { $feeder->run } );
 571
 572     $log->debug("Entering event loop. PID=$$");
 573
 574     my $result = $feeder->mpd->loop->run;
 575     $log->trace( "Got loop result of " . ( $result // 'undef' ) );
 576
 577     if ('reload' eq $result) {
 578         $log->notice("disconnecting");
 579         $feeder->stop;
 580
 581         exec( "$0", '--config', $feeder->cfg_file, '--skip-db-update' );
 582     }
 583 }