lib/App/MPD/Feeder.pm

   1 package App::MPD::Feeder;
   2
   3 use strict;
   4 use warnings;
   5 use utf8;
   6 use feature 'state';
   7
   8 use App::MPD::Feeder::Options;
   9 use App::MPD::Feeder::DB;
  10 use DBD::Pg;
  11 use DBI;
  12 use Getopt::Long;
  13 use IO::Async::Signal;
  14 use Log::Any qw($log);
  15 use Net::Async::MPD;
  16 use Object::Pad;
  17 use Syntax::Keyword::Try;
  18
  19
  20 class App::MPD::Feeder {
  21     has $cfg_file :reader;
  22     has $opt :reader;
  23     has $db :reader;
  24     has $db_needs_update :writer = 1;
  25     has $mpd :reader;
  26
  27 use constant DEFAULT_CONFIG_FILE => '/etc/mpd-feeder/mpd-feeder.conf';
  28
  29     ADJUST {
  30         Getopt::Long::Configure('pass_through');
  31         Getopt::Long::GetOptions('cfg|config=s' => \$cfg_file);
  32         Getopt::Long::Configure('no_pass_through');
  33
  34         $cfg_file //= DEFAULT_CONFIG_FILE if -e DEFAULT_CONFIG_FILE;
  35
  36         $self->configure;
  37
  38         $db_needs_update = 0 if $opt->skip_db_update;
  39     }
  40
  41     method configure {
  42         my $new_opt = App::MPD::Feeder::Options->new;
  43
  44         $new_opt->parse_config_file($cfg_file) if $cfg_file;
  45
  46         $new_opt->parse_command_line;
  47
  48         Log::Any::Adapter->set( Stderr => log_level => $new_opt->log_level );
  49
  50         $opt = $new_opt;
  51
  52         $db = App::MPD::Feeder::DB->new( opt => $opt );
  53     }
  54
  55     method connect_mpd {
  56         return if $mpd;
  57
  58         my %conn = ( auto_connect => 1 );
  59         $conn{host} = $opt->mpd_host if $opt->mpd_host;
  60         $conn{port} = $opt->mpd_port if $opt->mpd_port;
  61
  62         $mpd = Net::Async::MPD->new(%conn);
  63
  64         $mpd->on(
  65             close => sub {
  66                 die "Connection to MPD lost";
  67             }
  68         );
  69
  70         my $int_signal_handler = sub {
  71             state $signal_count = 0;
  72             $signal_count++;
  73             $log->debug("Signal received. Stopping loop");
  74             $mpd->loop->stop('quit');
  75
  76             if ( $signal_count > 1 ) {
  77                 $log->warn("Another signal received (#$signal_count)");
  78                 $log->warn("Exiting abruptly");
  79                 exit 2;
  80             }
  81         };
  82
  83         for (qw(TERM INT)) {
  84             $mpd->loop->add(
  85                 IO::Async::Signal->new(
  86                     name       => $_,
  87                     on_receipt => $int_signal_handler,
  88                 )
  89             );
  90         }
  91
  92         $mpd->loop->add(
  93             IO::Async::Signal->new(
  94                 name       => 'HUP',
  95                 on_receipt => sub {
  96                     $log->debug("SIGHUP received. Scheduling reload");
  97                     $mpd->loop->stop('reload');
  98                 },
  99             )
 100         );
 101
 102         $mpd->loop->add(
 103             IO::Async::Signal->new(
 104                 name       => 'USR1',
 105                 on_receipt => sub {
 106                     $log->debug("SIGUSR1 received. Dumping configuration to STDERR");
 107                     my $old = select \*STDERR;
 108                     try {
 109                         $opt->dump;
 110                     }
 111                     finally {
 112                         select $old;
 113                     }
 114                 },
 115             )
 116         );
 117     }
 118
 119     method connect_db {
 120         $db->connect($opt);
 121         $self->update_db;
 122     }
 123
 124     method update_db($force = undef) {
 125         if (!$db_needs_update and !$force) {
 126             $log->debug("Skipping DB update");
 127             return;
 128         }
 129
 130         $log->info('Updating song database');
 131         $self->connect_mpd;
 132
 133         my $rows = $mpd->send('listallinfo')->get;
 134
 135         $db->start_update;
 136         try {
 137             my $song_count;
 138
 139             foreach my $entry (@$rows) {
 140                 next unless exists $entry->{file};
 141
 142                 $self->db->store_song( $entry->{file},
 143                     $entry->{AlbumArtist} // $entry->{Artist},
 144                     $entry->{Album} );
 145                 $song_count++;
 146             }
 147
 148             $log->info("Updated data about $song_count songs");
 149
 150             $self->db->remove_stale_entries;
 151
 152             $self->db->finish_update;
 153
 154             $db_needs_update = 0;
 155         }
 156         catch {
 157             my $err = $@;
 158             $self->db->cancel_update;
 159             die $err;
 160         }
 161     }
 162
 163     method queue_songs($num = undef, $callback = undef) {
 164         $self->connect_db;
 165         if (!defined $num) {
 166             $self->connect_mpd;
 167             $mpd->send('playlist')->on_done(
 168                 sub {
 169                     my $present = scalar @{ $_[0] };
 170
 171                     $log->notice( "Playlist contains $present songs. Wanted: "
 172                             . $opt->target_queue_length );
 173                     if ( $present < $opt->target_queue_length ) {
 174                         $self->queue_songs(
 175                             $opt->target_queue_length - $present, $callback );
 176                     }
 177                     else {
 178                         $callback->() if $callback;
 179                     }
 180                 }
 181             );
 182
 183             return;
 184         }
 185
 186         my @list = $self->db->find_suitable_songs($num);
 187
 188         die "Found no suitable songs" unless @list;
 189
 190         if ( @list < $num ) {
 191             $log->warn(
 192                 sprintf(
 193                     'Found only %d suitable songs instead of %d',
 194                     scalar(@list), $num
 195                 )
 196             );
 197         }
 198
 199         $log->info("About to add $num songs to the playlist");
 200
 201         my @paths;
 202         for my $song (@list) {
 203             my $path = $song->{song};
 204             $path =~ s/"/\\"/g;
 205             push @paths, $path;
 206         }
 207
 208         $log->debug( "Adding " . join( ', ', map {"«$_»"} @paths ) );
 209         # MPD needs raw bytes
 210         utf8::encode($_) for @paths;
 211         my @commands;
 212         for (@paths) {
 213             push @commands, [ add => "\"$_\"" ];
 214         }
 215         $self->connect_mpd;
 216         my $f = $mpd->send( \@commands );
 217         $f->on_fail( sub { die @_ } );
 218         $f->on_done(
 219             sub {
 220                 $self->db->note_song_qeued($_) for @list;
 221                 $callback->(@_) if $callback;
 222             }
 223         );
 224     }
 225
 226     method prepare_to_wait_idle {
 227         $log->trace('declaring idle mode');
 228         $mpd->send('idle database playlist')->on_done(
 229             sub {
 230                 my $result = shift;
 231
 232                 if ( $result->{changed} eq 'database' ) {
 233                     $db_needs_update = 1;
 234                     $self->prepare_to_wait_idle;
 235                 }
 236                 elsif ( $result->{changed} eq 'playlist' ) {
 237                     $self->queue_songs( undef,
 238                         sub { $self->prepare_to_wait_idle } );
 239                 }
 240                 else {
 241                     use JSON;
 242                     $log->warn(
 243                         "Unknown result from idle: " . to_json($result) );
 244                     $self->prepare_to_wait_idle;
 245                 }
 246             }
 247         );
 248     }
 249
 250     method stop {
 251         undef $mpd;
 252
 253         $db->disconnect;
 254     }
 255
 256     method run_loop {
 257         $self->connect_mpd;
 258         $self->connect_db;
 259
 260         for ( ;; ) {
 261             $self->queue_songs( undef, sub { $self->prepare_to_wait_idle } );
 262
 263             $log->debug("Entering event loop. PID=$$");
 264
 265             my $result = $mpd->loop->run;
 266             $log->trace( "Got loop result of " . ( $result // 'undef' ) );
 267
 268             if ( 'reload' eq $result ) {
 269                 $log->notice("disconnecting");
 270                 $self->stop;
 271
 272                 my @exec = ( $0, '--config', $self->cfg_file, '--skip-db-update' );
 273                 if ( $log->is_trace ) {
 274                     $log->trace( 'exec '
 275                             . join( ' ', map { /\s/ ? "'$_'" : $_ } @exec ) );
 276                 }
 277                 exec(@exec);
 278             }
 279
 280             if ( 'quit' eq $result ) {
 281                 $log->trace("quitting because of 'quit' loop result");
 282                 $self->stop;
 283                 exit 0;
 284             }
 285         }
 286     }
 287 }
 288