lib/App/MPD/Feeder.pm

   1 package App::MPD::Feeder;
   2
   3 use strict;
   4 use warnings;
   5 use utf8;
   6 use feature 'state';
   7
   8 use App::MPD::Feeder::Options;
   9 use App::MPD::Feeder::DB;
  10 use DBD::Pg;
  11 use DBI;
  12 use Getopt::Long;
  13 use IO::Async::Signal;
  14 use Log::Any qw($log);
  15 use Net::Async::MPD;
  16 use Object::Pad;
  17 use Syntax::Keyword::Try;
  18
  19
  20 class App::MPD::Feeder {
  21     has $cfg_file :reader;
  22     has $opt :reader;
  23     has $db :reader;
  24     has $db_needs_update :writer = 1;
  25     has $mpd :reader;
  26
  27 use constant DEFAULT_CONFIG_FILE => '/etc/mpd-feeder/mpd-feeder.conf';
  28
  29     ADJUST {
  30         Getopt::Long::Configure('pass_through');
  31         Getopt::Long::GetOptions('cfg|config=s' => \$cfg_file);
  32         Getopt::Long::Configure('no_pass_through');
  33
  34         $cfg_file //= DEFAULT_CONFIG_FILE if -e DEFAULT_CONFIG_FILE;
  35
  36         $self->configure;
  37
  38         $db_needs_update = 0 if $opt->skip_db_update;
  39     }
  40
  41     method configure {
  42         my $new_opt = App::MPD::Feeder::Options->new;
  43
  44         $new_opt->parse_config_file($cfg_file) if $cfg_file;
  45
  46         $new_opt->parse_command_line;
  47
  48         Log::Any::Adapter->set( Stderr => log_level => $new_opt->log_level );
  49
  50         $opt = $new_opt;
  51
  52         $db = App::MPD::Feeder::DB->new( opt => $opt );
  53     }
  54
  55     method connect_mpd {
  56         return if $mpd;
  57
  58         my %conn = ( auto_connect => 1 );
  59         $conn{host} = $opt->mpd_host if $opt->mpd_host;
  60         $conn{port} = $opt->mpd_port if $opt->mpd_port;
  61
  62         $mpd = Net::Async::MPD->new(%conn);
  63
  64         $mpd->on(
  65             close => sub {
  66                 die "Connection to MPD lost";
  67             }
  68         );
  69
  70         my $int_signal_handler = sub {
  71             state $signal_count = 0;
  72             $signal_count++;
  73             $log->debug("Signal received. Stopping loop");
  74             $mpd->loop->stop('quit');
  75
  76             if ( $signal_count > 1 ) {
  77                 $log->warn("Another signal received (#$signal_count)");
  78                 $log->warn("Exiting abruptly");
  79                 exit 2;
  80             }
  81         };
  82
  83         for (qw(TERM INT)) {
  84             $mpd->loop->add(
  85                 IO::Async::Signal->new(
  86                     name       => $_,
  87                     on_receipt => $int_signal_handler,
  88                 )
  89             );
  90         }
  91
  92         $mpd->loop->add(
  93             IO::Async::Signal->new(
  94                 name       => 'HUP',
  95                 on_receipt => sub {
  96                     $log->debug("SIGHUP received. Scheduling reload");
  97                     $mpd->loop->stop('reload');
  98                 },
  99             )
 100         );
 101
 102         $mpd->loop->add(
 103             IO::Async::Signal->new(
 104                 name       => 'USR1',
 105                 on_receipt => sub {
 106                     $log->debug("SIGUSR1 received. Dumping configuration to STDERR");
 107                     my $old = select \*STDERR;
 108                     try {
 109                         $opt->dump;
 110                     }
 111                     finally {
 112                         select $old;
 113                     }
 114                 },
 115             )
 116         );
 117     }
 118
 119     method connect_db {
 120         $db->connect($opt);
 121         $self->update_db;
 122     }
 123
 124     method update_db($force = undef) {
 125         if (!$db_needs_update and !$force) {
 126             $log->debug("Skipping DB update");
 127             return;
 128         }
 129
 130         $log->info('Updating song database');
 131         $self->connect_mpd;
 132
 133         my $rows = $mpd->send('listallinfo')->get;
 134
 135         $log->trace('got all songs from MPD');
 136
 137         $db->start_update;
 138         try {
 139             my $song_count;
 140
 141             foreach my $entry (@$rows) {
 142                 next unless exists $entry->{file};
 143
 144                 $self->db->store_song( $entry->{file},
 145                     $entry->{AlbumArtist} // $entry->{Artist},
 146                     $entry->{Album} );
 147
 148                 $song_count++;
 149             }
 150
 151             my ($total_songs, $total_artists, $total_albums,
 152                 $new_songs,   $new_artists,   $new_albums
 153             ) = $self->db->finish_update;
 154
 155             $log->info(
 156                 "Updated data about $song_count songs (including $new_songs new), "
 157                     . "$total_artists artists (including $new_artists new) "
 158
 159                     . "and $total_albums albums (including $new_albums new)"
 160             );
 161
 162             $db_needs_update = 0;
 163         }
 164         catch {
 165             my $err = $@;
 166             $self->db->cancel_update;
 167             die $err;
 168         }
 169     }
 170
 171     method queue_songs($num = undef, $callback = undef) {
 172         $self->connect_db;
 173         if (!defined $num) {
 174             $self->connect_mpd;
 175             $mpd->send('playlist')->on_done(
 176                 sub {
 177                     my $present = scalar @{ $_[0] // [] };
 178
 179                     $log->notice( "Playlist contains $present songs. Wanted: "
 180                             . $opt->target_queue_length );
 181                     if ( $present < $opt->target_queue_length ) {
 182                         $self->queue_songs(
 183                             $opt->target_queue_length - $present, $callback );
 184                     }
 185                     else {
 186                         $callback->() if $callback;
 187                     }
 188                 }
 189             );
 190
 191             return;
 192         }
 193
 194         my @list = $self->db->find_suitable_songs($num);
 195
 196         die "Found no suitable songs" unless @list;
 197
 198         if ( @list < $num ) {
 199             $log->warn(
 200                 sprintf(
 201                     'Found only %d suitable songs instead of %d',
 202                     scalar(@list), $num
 203                 )
 204             );
 205         }
 206
 207         $log->info("About to add $num songs to the playlist");
 208
 209         my @paths;
 210         for my $song (@list) {
 211             my $path = $song->{song};
 212             $path =~ s/"/\\"/g;
 213             push @paths, $path;
 214         }
 215
 216         $log->debug( "Adding " . join( ', ', map {"«$_»"} @paths ) );
 217         # MPD needs raw bytes
 218         utf8::encode($_) for @paths;
 219         my @commands;
 220         for (@paths) {
 221             push @commands, [ add => "\"$_\"" ];
 222         }
 223         $self->connect_mpd;
 224         my $f = $mpd->send( \@commands );
 225         $f->on_fail( sub { die @_ } );
 226         $f->on_done(
 227             sub {
 228                 $self->db->note_song_qeued($_) for @list;
 229                 $callback->(@_) if $callback;
 230             }
 231         );
 232     }
 233
 234     method prepare_to_wait_idle {
 235         $log->trace('declaring idle mode');
 236         $mpd->send('idle database playlist')->on_done(
 237             sub {
 238                 my $result = shift;
 239
 240                 undef $idler;
 241
 242                 my $changed = $result->{changed} // '';
 243
 244                 if ( $changed eq 'database' ) {
 245                     $db_needs_update = 1;
 246                     $self->prepare_to_wait_idle;
 247                 }
 248                 elsif ( $changed eq 'playlist' ) {
 249                     $self->queue_songs( undef,
 250                         sub { $self->prepare_to_wait_idle } );
 251                 }
 252                 elsif ( $changed eq '' ) {
 253                     $log->debug("got no changes from idle");
 254                     $self->prepare_to_wait_idle;
 255                 }
 256                 else {
 257                     use JSON;
 258                     $log->warn(
 259                         "Unknown result from idle: " . to_json($result) );
 260                     $self->prepare_to_wait_idle;
 261                 }
 262             }
 263         );
 264     }
 265
 266     method stop {
 267         undef $mpd;
 268
 269         $db->disconnect;
 270     }
 271
 272     method run_loop {
 273         $self->connect_mpd;
 274         $self->connect_db;
 275
 276         for ( ;; ) {
 277             $self->queue_songs( undef, sub { $self->prepare_to_wait_idle } );
 278
 279             $log->debug("Entering event loop. PID=$$");
 280
 281             my $result = $mpd->loop->run;
 282             $log->trace( "Got loop result of " . ( $result // 'undef' ) );
 283
 284             if ( 'reload' eq $result ) {
 285                 $log->notice("disconnecting");
 286                 $self->stop;
 287
 288                 my @exec = ( $0, '--config', $self->cfg_file, '--skip-db-update' );
 289                 if ( $log->is_trace ) {
 290                     $log->trace( 'exec '
 291                             . join( ' ', map { /\s/ ? "'$_'" : $_ } @exec ) );
 292                 }
 293                 exec(@exec);
 294             }
 295
 296             if ( 'quit' eq $result ) {
 297                 $log->trace("quitting because of 'quit' loop result");
 298                 $self->stop;
 299                 exit 0;
 300             }
 301         }
 302     }
 303 }
 304